/*
 *	Author: Clarky
 *	Usage:
 *		[this] call CLRK_fnc_initBaseHQInteractions;
 *	 
 *		Intended to run locally on each client.
 *	
 */

params ["_hq"];

_hq addAction [
	"<t color='#FFD700'>Check Total Materiel</t>",
	
	{
		params ["_target", "_caller"];		
		[
			"CLRK_MaterielCheck",
			[
				_target, 
				_caller
			]
		] call CBA_fnc_serverEvent;
	},
	nil,
	1,
	true,
	false,
	"",
	"true",
	6
];

_hq addAction [
	"<t color='#55cbda'>Check Fortify Budget</t>",
	{
		params ["_target", "_caller"];
		private _msg = format ["Current Fortify Budget: %1", [side _caller] call ace_fortify_fnc_getBudget];
		[
			"CLRK_ShowMessage",
			[
				3,
				1,
				_msg
			],
			_caller
		] call CBA_fnc_targetEvent;
	},
	nil,
	1,
	true,
	false,
	"",
	"true", // Figure out a way to lock this to player side checks (macros?)
	6
];

_hq addAction [
	"<t color='#da55ce'>Add Fortify Budget - $100</t>",
	{
		params ["_target", "_caller"];

		[
			"CLRK_FortifyBudgetAdd",
			[
				_target,
				_caller
			]
		] call CBA_fnc_serverEvent;
			//[side _caller, 100, true] call ace_fortify_fnc_updateBudget;
	},
	nil,
	1,
	true,
	false,
	"",
	"true", // Figure out a way to lock this to player side checks (macros?)
	6
];