/*
	Author: Clarky
	Usage:
		[this] call CLRK_fnc_initSupplyDepotInteractions;
	 
	Intended to run locally on each client.
	
*/

params ["_depot"];

if (isNull _depot) exitWith {hint "Object ain't exist";};
if !(_depot getVariable ["isOreDepot", false]) exitWith {hint "Object ain't ore depot";};

// Prevent duplicate actions if script runs again
if (_depot getVariable ["oreInteractionsAdded", false]) exitWith {};

_depot setVariable ["oreInteractionsAdded", true];

//////////////////////////////////////////////////////////////////
// INIT STATUS ACTION
//////////////////////////////////////////////////////////////////

_depot addAction [
	"<t color='#b96331'>Check Ore Status</t>",
	
	{
		params ["_target", "_caller"];
		
		private _current =
			_target getVariable ["currentOre", 0];
		
		private _max =
			_target getVariable ["maxOre", 300];
		
		[
			"CLRK_ShowMessage",
			[
				3, 
				1, 
				format 
				[
					"ORE DEPOT STORAGE<br />Ore: %1 / %2", 
					_current, 
					_max
				]
			],
			_caller
		] call CBA_fnc_targetEvent;
	},
	nil,
	1,
	true,
	false,
	"",
	"true",
	6
];